Форма входа
Читем онлайн Adobe Flash. Создание аркад, головоломок и других игр с помощью ActionScript - Гэри Розенцвейг
Шрифт:
-
+
Интервал:
-
+
Закладка:
Сделать
function startGame() {
gameLevel = 1;
startLevel();
}Функция startLevel выполняет множество задач. Сначала она переводит ролик к кадру в соответствии со значением переменной gameLevel, затем помещает корабль вверху экрана. Скорость корабля, которая определяется величинами dx и dy, обнуляется. Для увеличения скорости корабля и для того, чтобы он начал двигаться вниз, используется переменная gravity.
В массивах hitPoints и footPoints содержатся координаты некоторых точек относительно центра корабля. Для определения, коснулся ли корабль поверхности луны, используются элементы массива hitPoints. А оба элемента массива footPoints нужны, чтобы определить, находятся ли обе опоры лунохода на посадочной площадке.
В массиве pads хранятся имена трех клипов посадочных площадок. На одном уровне имеется всего лишь две посадочные площадки, но язык ActionScript этого не учитывает.function startLevel() {
gotoAndStop("level"+gameLevel);
// Размещаем клип корабля.
ship._x = 275;
ship._x = 25;
// Корабль не движется.
ship.dx = 0;
ship.dy = 0;
// Инициализируем гравитацию.
gravity = .1;
// Инициализируем индикатор горючего.
fuel = 100;
showFuel();
// Определяем точки корабля, которые могут коснуться поверхности Луны.
hitPoints = new Array();
hitPoints.push({x:-9, y:13});
hitPoints.push({x:9, y:13});
hitPoints.push({x:0, y:-10});
hitPoints.push({x:-9, y:-7});
hitPoints.push({x:8, y:-7});
// Определяем координаты опор лунохода.
footPoints = new Array();
footPoints.push({x:-9, y:13});
footPoints.push({x:9, y:13});
// Создаем массив из клипов "pad" (посадочная площадка).
pads = new Array();
for (i=0; i<3; i++) {
pads.push(_root["pad"+i]);
}
}В каждом кадре посредством клипа «actions» вызывается функция moveShip, которая, в свою очередь, вызывает множество небольших функций для управления кораблем. Всегда лучше разбивать большой фрагмент кода на несколько небольших функций.
function moveShip() {
shipThrusters();
shipMovement();
checkForLand();
checkForCrash();
}Функция shipThrusters проверяет, осталось ли еще горючее, если нет, то клип «ship» переходит к кадру «normal». В противном случае, если игрок нажимает на одну из клавиш со стрелками «вверх», «влево» или «вправо», включается соответствующий ускоритель. Клип «ship» переходит к соответствующему кадру, и чтобы отразить эффект действия ускорителя, изменяются значения dx и dy. Также уменьшается количество топлива.
function shipThrusters() {
// Проверяем ускорители и корректируем скорость.
if (fuel < 0) {
ship.gotoAndStop("normal");
} else if (Key.isDown(Key.UP)) {
ship.dy -= .4;
ship.gotoAndStop("up");
fuel -= 2;
showFuel();
} else if (Key.isDown(Key.LEFT)) {
ship.dx -= .2;
ship.gotoAndStop("left");
fuel -= 1;
showFuel();
} else if (Key.isDown(Key.RIGHT)) {
ship.dy += .2;
ship.gotoAndStop("right");
fuel -= 1;
showFuel();
} else {
// Не включен ни один из ускорителей.
ship.gotoAndStop("normal");
}
}Функция shipMovement изменяет скорость корабля согласно гравитации и перемещает корабль в зависимости от скорости лунохода.
function shipMovement() {
// Гравитация заставляет корабль двигаться вниз.
ship.dy += gravity;
// Перемещаем корабль.
ship._x += ship.dx;
ship._y += ship.dy;
}Функция checkForLand проверяет массив footPoints: находится ли хоть одна опора лунохода внутри клипа «pad». Если там нет ни одной опоры, переменной landed присваивается значение false. Такое же значение присваивается и в том случае, когда скорость лунохода больше трех единиц, поскольку данная скорость слишком высока для того, чтобы луноход смог совершить посадку. Если после этого значение переменной landed все еще равно true, значит, луноход удачно совершил посадку. Все, что теперь необходимо сделать, – перейти к следующему кадру в основной временной шкале и увеличить значение переменной gameLevel на единицу.
function checkForLand() {
// Выясняем, обе ли опоры находятся на посадочной площадке.
landed = true;
for(i=0; i<footPoints.length; i++) {
// Просматриваем все площадки.
footDown = false;
for(j=0; j<pads.length; j++) {
// Проверяем, находится ли опора на площадке.
if (pads[j].hitTest(ship._x+footPoints[i].x, ship._y+footPoints[i].y, true)) {
footDown = true;
break;
}
}
// Если опора не находится на площадке,
// значит, корабль не совершил посадку.
if (!footDown) {
landed = false;
break;
}
}
// Проверяем, не слишком ли быстро движется корабль.
if (ship.dy > 3.0) landed = false;
if (landed) {
// Посадка совершена.
gotoAndPlay(_currentFrame+1);
gameLevel++;
}
}С другой стороны, необходимо проверять, взорвался луноход или нет. В массиве hitPoints содержится список координат точек вокруг корабля: двух опор, середины каждой стороны, вершины и центра днища. Так как невозможно определить, полностью ли один объект накладывается на другой, вы просто проверяете эти точки. Если какая-то из них оказалась внутри элемента «activeground», тогда корабль разбился. У клипа «Ground – level X» на каждом уровне – имя экземпляра «activeground».
function checkForCrash() {
// Корабль не совершил посадку. Проверяем, коснулся ли он поверхности Луны.
if (!landed) {
// Просматриваем все возможные точки касания.
for(i=0; i<hitPoints.length; i++) {
// Проверяем, не коснулся ли корабль поверхности Луны в этой точке.
if (activeground.hitTest(ship._x+hitPoints[i].x, ship._y+hitPoints[i].y, true)) {
ship.gotoAndPlay("explode");
// Уменьшаем количество жизней или завершаем игру.
gotoAndPlay("lost ship");
break;
}
}
}
}Еще одна полезная функция в этом ролике – showFuel. Она берет клип «meter» и присваивает его свойству _xscale величину fuel. Так как сначала значение переменной fuel (запас горючего) равно 100, а затем уменьшается до 0, его легко использовать для свойства _xscale. Если бы диапазон значений fuel был другим, вам бы пришлось сначала преобразовать их так, чтобы они находились в диапазоне от 0 до 100, а лишь затем присваивать их свойству _xscale.
function showFuel() {
gauge.meter._xscale = fuel;
}...Совет
Обратите внимание: для того чтобы размеры клипа "meter" уменьшались справа налево, необходимо поместить центр клипа так, чтобы центр прямоугольника располагался справа от него. Если центр клипа окажется слева, то изменение величины _xscale приведет к тому, что объект будет сокращаться к центру, а не справа налево.
К сведению
В этом ролике к каждой кнопке Play прикреплена одна строчка кода. Просмотрите каждый из этих сценариев, чтобы понять, к какому кадру переходит ролик или какая функция вызывается.
Обратите внимание, что во всех трех типах ускорителей использовалась одна и та же анимация – thrust animation. Для левого и правого ускорителей клип поворачивался на 90° или на -90°. Размер анимации боковых ускорителей был уменьшен, так как предполагается, что они слабее основного ускорителя.
Другие возможности
В этой игре очки не начисляются. Вы же можете добавлять очки за каждую успешную посадку, причем за посадку на труднодоступные посадочные площадки начислять больше обычного. Также можно предоставлять премию за скорость и объем неиспользованного топлива. Добавить уровни к игре очень просто, для этого нужно только нарисовать рельеф. Когда вы исчерпаете все свои идеи, попробуйте изменить код таким образом, чтобы на более высоких уровнях с тем же рельефом корабль имел меньше топлива или была более сильная гравитация.
Платформенный скроллер
Исходный файл: Platformfla
После первой волны аркадных игр, которая спала где-то в начале 80-х, следующим значительным течением было появление игр типа платформенный скроллер. Этот жанр приобрел широкую популярность после появления серии игр "Mario Bros" от компании Nintendo. В конце 80-х платформенные скроллеры были абсолютным фаворитом среди консольных игр. Игры этого типа продолжают выходить и сегодня.
Игровой процесс типичного скроллера состоит в следующем: герой игры передвигается взад и вперед по двухмерному миру (вид сбоку). Игровое пространство имеет несколько горизонтальных уровней – платформ, и игрок может прыгать и перемещаться по ним. Цель состоит в собирании различных предметов, за которые начисляются очки, и в том, чтобы избегать (а также уничтожать) других созданий игрового мира.
На рисунке 16.8 показан простенький пример скроллера с лисой в главной роли. Лиса может перемещаться туда-сюда по горизонтали и прыгать по платформам. При этом ей необходимо собирать орехи и избегать кроликов.
Рисунок 16.8 . Реализованный во Flash платформенный скроллер содержит все основные элементы этого жанра
Задача проекта
Платформенный скроллер может быть довольно глобальным проектом. Противников (в нашем случае кроликов) можно атаковать, например, напрыгивая на них, некоторые объекты могут давать игроку специальные возможности, такие как увеличение скорости или возможность поражать неприятеля, который неуязвим в остальных случаях.
Мы же постараемся сделать максимально простую игру, сосредоточив усилия на воплощении основных особенностей жанра. Лиса будет иметь возможность перемещаться взад-вперед и прыгать. Платформы в виде блоков будут препятствовать перемещению игрока по горизонтали, так что ему придется запрыгивать на них и проделывать часть пути поверху.
На этой странице вы можете бесплатно читать книгу Adobe Flash. Создание аркад, головоломок и других игр с помощью ActionScript - Гэри Розенцвейг бесплатно.
Похожие на Adobe Flash. Создание аркад, головоломок и других игр с помощью ActionScript - Гэри Розенцвейг книги
- Хочу в геймдев! Основы игровой разработки для начинающих - Вячеслав Николаевич Уточкин - Программирование
- Python для детей. Анимация с черепашьей графикой - Виктор Рабинович - Прочая детская литература / Программирование
- Изучай Haskell во имя добра! - Миран Липовача - Программирование
- QT 4: программирование GUI на С++ - Жасмин Бланшет - Программирование
- Программист-фанатик - Чед Фаулер - Программирование
- Эффективное использование STL - Скотт Мейерс - Программирование
- Настраиваем монитор с помощью утилит Free Monitor Manager и Gamma Panel - Евгений Владимирович Сапожинский - Программирование
- Убейте дракона! Как писать блестящие сценарии для видеоигр - Роберт Дентон Брайант - Программирование
- ДИАЛОГ С КОМПЬЮТЕРОМ - Александр Журавлев - Программирование
- От «Энигмы» до ChatGPT - Рустам Агамалиев - Программирование / Экономика
